home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Amoszine 4
/
Amoszine 4 (Disk 2 of 3).adf
/
Intuition_Procs
/
intui.lha
/
Demo_1.Amos
/
Demo_1.amosSourceCode
Wrap
AMOS Source Code
|
1992-02-26
|
2KB
|
71 lines
' Demo of OpenScreen, CloseScreen and WritePixel
' note that during the demo the drag bar and back/front gadgets may be used
'
Amos To Back
'
Wait 50
'
_OPENSCREEN[0,0,320,200,2,0,1,2,15,0,0,0," AMOS And Intuition "]
'
For B=12 To 199
For A=0 To 319
_WRITEPIXEL[_IS,A,B]
Next
Next
'
_CLOSESCREEN[_IS]
'
Wait 50
'
Amos To Front
'
Edit
'
Procedure _OPENSCREEN[X,Y,W,H,D,F,B,V,S,C,G,M,T$]
Global _IS
T$=T$+Chr$(0)
Reserve As Work 10,32
A=Start(10)
Doke A,X : Add A,2 : Rem -- x_pos:
Doke A,Y : Add A,2 : Rem -- y_pos:
Doke A,W : Add A,2 : Rem -- width:
Doke A,H : Add A,2 : Rem -- height:
Doke A,D : Add A,2 : Rem -- depth:
Poke A,F : Add A,1 : Rem -- detail_pen:
Poke A,B : Add A,1 : Rem -- block_pen:
Doke A,V : Add A,2 : Rem -- view_modes:
Doke A,S : Add A,2 : Rem -- screen_type:
Loke A,C : Add A,4 : Rem -- font:
Loke A,Varptr(T$) : Add A,4 : Rem -- title:
Loke A,G : Add A,4 : Rem -- gadgets:
Loke A,M : Rem -- bitmap:
Areg(0)=Start(10)
_IS=Intcall(-198)
Erase 10
End Proc
Procedure _CLOSESCREEN[_IS]
Areg(0)=_IS : Rem -- Screen Handle In A0
NULL=Intcall(-66)
End Proc
Procedure _WRITEPIXEL[_IS,X,Y]
Areg(1)=_IS+84
Dreg(0)=X : Rem -- X Pos
Dreg(1)=Y : Rem -- Y Pos
NULL=Gfxcall(-324)
End Proc